JavaScript 1.4 Grammar

This is an LR(1) grammar written by waldemar that describes the state of ECMAScript as of February 1999. The grammar is complete except for semicolon insertion (the OptionalSemicolon grammar state can sometimes reduce to «empty») and distinguishing RegularExpression from / and /=. Also, there is some controversy about elision in array literals, so this feature has been omitted for now.

Grammar syntax

Grammar productions may expand nonterminals into empty right sides. Such right sides are indicated as «empty».

A number of rules in the grammar occur in groups of analogous rules. Rather than list them individually, these groups have been summarized using the shorthand illustrated by the example below:

introduce grammar arguments α and β. If these arguments later parametrize the nonterminal on the left side of a rule, that rule is implicitly replicated into a set of rules in each of which a grammar argument is consistently substituted by one of its variants. For example,

AssignmentExpression^α,β ⇒

ConditionalExpression^α,β

| LeftSideExpression^α = AssignmentExpression^normal,β

| LeftSideExpression^α CompoundAssignment AssignmentExpression^normal,β

AssignmentExpression^{normal,allowIn} ⇒

ConditionalExpression^{normal,allowIn}

| LeftSideExpression^normal = AssignmentExpression^{normal,allowIn}

| LeftSideExpression^normal CompoundAssignment AssignmentExpression^{normal,allowIn}

AssignmentExpression^normal,noIn ⇒

ConditionalExpression^normal,noIn

| LeftSideExpression^normal = AssignmentExpression^normal,noIn

| LeftSideExpression^normal CompoundAssignment AssignmentExpression^normal,noIn

AssignmentExpression^{initial,allowIn} ⇒

ConditionalExpression^{initial,allowIn}

| LeftSideExpression^initial = AssignmentExpression^{normal,allowIn}

| LeftSideExpression^initial CompoundAssignment AssignmentExpression^{normal,allowIn}

AssignmentExpression^initial,noIn ⇒

ConditionalExpression^initial,noIn

| LeftSideExpression^initial = AssignmentExpression^normal,noIn

| LeftSideExpression^initial CompoundAssignment AssignmentExpression^normal,noIn

AssignmentExpression^{normal,allowIn} is now an unparametrized nonterminal and processed normally by the grammar.

Some of the expanded rules (such as the fourth one in the example above) may be unreachable from the starting nonterminal Program; these are ignored.

Expressions

Primary Expressions

PrimaryExpression^normal ⇒

SimpleExpression

| FunctionExpression

| ObjectLiteral

PrimaryExpression^initial ⇒ SimpleExpression

SimpleExpression ⇒

this

| null

| true

| false

| Number

| String

| Identifier

| RegularExpression

| ParenthesizedExpression

| ArrayLiteral

ParenthesizedExpression ⇒ ( Expression^{normal,allowIn} )

Function Expressions

FunctionExpression ⇒

AnonymousFunction

| NamedFunction

Object Literals

ObjectLiteral ⇒

{ }

| { FieldList }

FieldList ⇒

LiteralField

| FieldList , LiteralField

LiteralField ⇒ Identifier : AssignmentExpression^{normal,allowIn}

Array Literals

ArrayLiteral ⇒

[ ]

| [ ElementList ]

ElementList ⇒

LiteralElement

| ElementList , LiteralElement

LiteralElement ⇒ AssignmentExpression^{normal,allowIn}

Left-Side Expressions

LeftSideExpression^α ⇒

CallExpression^α

| ShortNewExpression

CallExpression^α ⇒

PrimaryExpression^α

| FullNewExpression

| CallExpression^α MemberOperator

| CallExpression^α Arguments

FullNewExpression ⇒ new FullNewSubexpression Arguments

ShortNewExpression ⇒ new ShortNewSubexpression

FullNewSubexpression ⇒

PrimaryExpression^normal

| FullNewExpression

| FullNewSubexpression MemberOperator

ShortNewSubexpression ⇒

FullNewSubexpression

| ShortNewExpression

MemberOperator ⇒

[ Expression^{normal,allowIn} ]

| . Identifier

Arguments ⇒

( )

| ( ArgumentList )

ArgumentList ⇒

AssignmentExpression^{normal,allowIn}

| ArgumentList , AssignmentExpression^{normal,allowIn}

Postfix Operators

PostfixExpression^α ⇒

LeftSideExpression^α

| LeftSideExpression^α ++

| LeftSideExpression^α --

Unary Operators

UnaryExpression^α ⇒

PostfixExpression^α

| delete LeftSideExpression^normal

| void UnaryExpression^normal

| typeof UnaryExpression^normal

| ++ LeftSideExpression^normal

| -- LeftSideExpression^normal

| + UnaryExpression^normal

| - UnaryExpression^normal

| ~ UnaryExpression^normal

| ! UnaryExpression^normal

Multiplicative Operators

MultiplicativeExpression^α ⇒

UnaryExpression^α

| MultiplicativeExpression^α * UnaryExpression^normal

| MultiplicativeExpression^α / UnaryExpression^normal

| MultiplicativeExpression^α % UnaryExpression^normal

Additive Operators

AdditiveExpression^α ⇒

MultiplicativeExpression^α

| AdditiveExpression^α + MultiplicativeExpression^normal

| AdditiveExpression^α - MultiplicativeExpression^normal

Bitwise Shift Operators

ShiftExpression^α ⇒

AdditiveExpression^α

| ShiftExpression^α << AdditiveExpression^normal

| ShiftExpression^α >> AdditiveExpression^normal

| ShiftExpression^α >>> AdditiveExpression^normal

Relational Operators

RelationalExpression^α,allowIn ⇒

ShiftExpression^α

| RelationalExpression^α,allowIn < ShiftExpression^normal

| RelationalExpression^α,allowIn > ShiftExpression^normal

| RelationalExpression^α,allowIn <= ShiftExpression^normal

| RelationalExpression^α,allowIn >= ShiftExpression^normal

| RelationalExpression^α,allowIn instanceof ShiftExpression^normal

| RelationalExpression^α,allowIn in ShiftExpression^normal

RelationalExpression^α,noIn ⇒

ShiftExpression^α

| RelationalExpression^α,noIn < ShiftExpression^normal

| RelationalExpression^α,noIn > ShiftExpression^normal

| RelationalExpression^α,noIn <= ShiftExpression^normal

| RelationalExpression^α,noIn >= ShiftExpression^normal

| RelationalExpression^α,noIn instanceof ShiftExpression^normal

Equality Operators

EqualityExpression^α,β ⇒

RelationalExpression^α,β

| EqualityExpression^α,β == RelationalExpression^normal,β

| EqualityExpression^α,β != RelationalExpression^normal,β

| EqualityExpression^α,β === RelationalExpression^normal,β

| EqualityExpression^α,β !== RelationalExpression^normal,β

Binary Bitwise Operators

BitwiseAndExpression^α,β ⇒

EqualityExpression^α,β

| BitwiseAndExpression^α,β & EqualityExpression^normal,β

BitwiseXorExpression^α,β ⇒

BitwiseAndExpression^α,β

| BitwiseXorExpression^α,β ^ BitwiseAndExpression^normal,β

BitwiseOrExpression^α,β ⇒

BitwiseXorExpression^α,β

| BitwiseOrExpression^α,β | BitwiseXorExpression^normal,β

Binary Logical Operators

LogicalAndExpression^α,β ⇒

BitwiseOrExpression^α,β

| LogicalAndExpression^α,β && BitwiseOrExpression^normal,β

LogicalOrExpression^α,β ⇒

LogicalAndExpression^α,β

| LogicalOrExpression^α,β || LogicalAndExpression^normal,β

Conditional Operator

ConditionalExpression^α,β ⇒

LogicalOrExpression^α,β

| LogicalOrExpression^α,β ? AssignmentExpression^normal,β : AssignmentExpression^normal,β

Assignment Operators

AssignmentExpression^α,β ⇒

ConditionalExpression^α,β

| LeftSideExpression^α = AssignmentExpression^normal,β

| LeftSideExpression^α CompoundAssignment AssignmentExpression^normal,β

CompoundAssignment ⇒

*=

| /=

| %=

| +=

| -=

| <<=

| >>=

| >>>=

| &=

| ^=

| |=

Expressions

Expression^α,β ⇒

AssignmentExpression^α,β

| Expression^α,β , AssignmentExpression^normal,β

OptionalExpression ⇒

Expression^{normal,allowIn}

| «empty»

Statements

Statement^ω ⇒

EmptyStatement

| ExpressionStatement OptionalSemicolon

| VariableDefinition OptionalSemicolon

| Block

| LabeledStatement^ω

| IfStatement^ω

| SwitchStatement

| DoStatement OptionalSemicolon

| WhileStatement^ω

| ForStatement^ω

| WithStatement^ω

| ContinueStatement OptionalSemicolon

| BreakStatement OptionalSemicolon

| ReturnStatement OptionalSemicolon

| ThrowStatement OptionalSemicolon

| TryStatement

OptionalSemicolon ⇒ ;

Empty Statement

EmptyStatement ⇒ ;

Expression Statement

ExpressionStatement ⇒ Expression^{initial,allowIn}

Variable Definition

VariableDefinition ⇒ var VariableDeclarationList^allowIn

VariableDeclarationList^β ⇒

VariableDeclaration^β

| VariableDeclarationList^β , VariableDeclaration^β

VariableDeclaration^β ⇒ Identifier VariableInitializer^β

VariableInitializer^β ⇒

«empty»

| = AssignmentExpression^normal,β

Block

Block ⇒ { BlockStatements }

BlockStatements ⇒

«empty»

| BlockStatementsPrefix

BlockStatementsPrefix ⇒

Statement^full

| BlockStatementsPrefix Statement^full

Labeled Statements

LabeledStatement^ω ⇒ Identifier : Statement^ω

If Statement

IfStatement^full ⇒

if ParenthesizedExpression Statement^full

| if ParenthesizedExpression Statement^noShortIf else Statement^full

IfStatement^noShortIf ⇒ if ParenthesizedExpression Statement^noShortIf else Statement^noShortIf

Switch Statement

SwitchStatement ⇒

switch ParenthesizedExpression { }

| switch ParenthesizedExpression { CaseGroups LastCaseGroup }

CaseGroups ⇒

«empty»

| CaseGroups CaseGroup

CaseGroup ⇒ CaseGuards BlockStatementsPrefix

LastCaseGroup ⇒ CaseGuards BlockStatements

CaseGuards ⇒

CaseGuard

| CaseGuards CaseGuard

CaseGuard ⇒

case Expression^{normal,allowIn} :

| default :

Do-While Statement

DoStatement ⇒ do Statement^full while ParenthesizedExpression

While Statement

WhileStatement^ω ⇒ while ParenthesizedExpression Statement^ω

For Statements

ForStatement^ω ⇒

for ( ForInitializer ; OptionalExpression ; OptionalExpression ) Statement^ω

| for ( ForInBinding in Expression^{normal,allowIn} ) Statement^ω

ForInitializer ⇒

«empty»

| Expression^normal,noIn

| var VariableDeclarationList^noIn

ForInBinding ⇒

LeftSideExpression^normal

| var VariableDeclaration^noIn

With Statement

WithStatement^ω ⇒ with ParenthesizedExpression Statement^ω

Continue and Break Statements

ContinueStatement ⇒ continue OptionalLabel

BreakStatement ⇒ break OptionalLabel

OptionalLabel ⇒

«empty»

| Identifier

Return Statement

ReturnStatement ⇒ return OptionalExpression

Throw Statement

ThrowStatement ⇒ throw Expression^{normal,allowIn}

Try Statement

TryStatement ⇒

try Block CatchClauses

| try Block FinallyClause

| try Block CatchClauses FinallyClause

CatchClauses ⇒

CatchClause

| CatchClauses CatchClause

CatchClause ⇒ catch ( Identifier ) Block

FinallyClause ⇒ finally Block

Function Definition

FunctionDefinition ⇒ NamedFunction

AnonymousFunction ⇒ function FormalParametersAndBody

NamedFunction ⇒ function Identifier FormalParametersAndBody

FormalParametersAndBody ⇒ ( FormalParameters ) { TopStatements }

Grammar syntax

Expressions

Primary Expressions

Function Expressions

Object Literals

Array Literals

Left-Side Expressions

Postfix Operators

Unary Operators

Multiplicative Operators

Additive Operators

Bitwise Shift Operators

Relational Operators

Equality Operators

Binary Bitwise Operators

Binary Logical Operators

Conditional Operator

Assignment Operators

Expressions

Statements

Empty Statement

Expression Statement

Variable Definition

Block

Labeled Statements

If Statement

Switch Statement

Do-While Statement

While Statement

For Statements

With Statement

Continue and Break Statements

Return Statement

Throw Statement

Try Statement

Function Definition

Programs